#!/usr/bin/awk -f
#
# This script generates a more readable log from a sniffusb log.
#
# Usage: parseusbsnoop.awk < usbsnoop.log > log1.txt
#
# It works with sniffusb 1.8 ("UsbSnoop compiled on Jan 18 2003 22:41:32")
#
# This script is based on a idea by Thomas SOUMARMON (soumarmt hotmail com).
#
# Author: Frank Zago (base work)
#         Gerhard Jaeger (some formatting stuff)
#
# License: GPL v2
#
# Note: this script does its best to ignore returning URB from interrupts.



BEGIN {

# number of data until the output will be skipped
	skiplen = 256;

# 0 means don't format the output, > 0 the number of output values per line
	nl = 8;

# if you don't want the timestamps, set "want_time" to 0
	want_time = 1;

# the "run-time" vars
	action = ""; 

	buffer[0] = 0;

	rtype = 0;
	request = 0;
	value = 0;
	rindex = 0;

	ignore_urb = 0;

	last_int_urb = -1;
}

{
	if ($4 == "URB" ) {
	
		if( $1 == "*******" ) {
# comment line
			printf("warning: line %d ignored:\n%s\n",NR,$0);
			ignore_urb = 1;
			next;
		}
# get the time field
		tt = strtonum(substr($1,2));
		time = "";
		fill = "\n                                                        ";
		if( want_time ) {
			time = sprintf( "%9dms ", tt );
			fill = fill "               ";
		}
# New URB
		this_urb = strtonum($5);

		if (this_urb == last_int_urb) {
# this interrupt URB is coming back
			ignore_urb = 1;
			next;
		}
# this happens, when we try to analyze only a portion of log
		if( last_int_urb == -1 ) {
			last_int_urb = this_urb - 1;
			urb = this_urb - 1;
		}

		if (way == "down" && $7 == "down") {
# This URB is also an interrupt URB
			printf "%sURB %5d skip\n", time, this_urb;
			ignore_urb = 1;
			last_int_urb = this_urb;
			next;
		}
		
		old_way = way;
		way = $7;

		if (way == "back") {
			if (urb != this_urb) {
				printf "got URB back %d instead of %d at line %d\n", this_urb, urb, NR;
				exit;
			}
		}
		else if (way == "down") {
			
			ignore_urb = 0;

			if (this_urb != urb+1 && this_urb != urb+2) {
				printf "expected URB down %d instead of %d at line %d\n", urb+1, this_urb, NR;
				exit;
			}

			if (last_int_urb != urb) {

				if (endpoint == "CONTROL") {
					printf "%sURB %5d  %c%c control  0x%02x 0x%02x 0x%02x 0x%02x len %5d", time, urb, last_action, action, rtype, request, value, rindex, buflen;
					if (direction == "OUT") {
						printf(" wrote ");
					} else {
						printf(" read  ");
					}

					j = 0;
					for (i=0; i<buflen; i++) {
						printf("0x%02x ", buffer[i]);
						j++;
						if( j == nl && nl != 0 && i < buflen-1 ) {
							j = 0;
							printf("%s", fill);
						}
					}
					printf("\n");
				}
				else if (endpoint == "BULK_IN") {
					printf "%sURB %5d  %c%c bulk_in                      len %5d read  ", time, urb, last_action, action, buflen;

					if (buflen > skiplen) {
						printf("SKIPPED\n");
					} else {
						j = 0;
						for (i=0; i<buflen; i++) {
							printf("0x%02x ", buffer[i]);
							j++;
							if( j == nl && nl != 0 && i < buflen-1 ) {
								j = 0;
								printf("%s", fill);
							}
						}
						printf("\n");
					}
				}
				else if (endpoint == "BULK_OUT") {
					printf "%sURB %5d  %c%c bulk_out                     len %5d wrote ", time, urb, last_action, action, buflen;
				
					if (buflen > skiplen) {
						printf("SKIPPED\n");
					} else {
						j = 0;
						for (i=0; i<buflen; i++) {
							printf("0x%02x ", buffer[i]);
							j++;
							if( j == nl && nl != 0 && i < buflen-1 ) {
								j = 0;
								printf("%s", fill);
							}
						}
						printf("\n");
					}
				}
			}
		}
		else {
			printf("BAD line %d", NR);
		}

		/* Next urb */
		urb = strtonum($5);
	}

	if (ignore_urb) {
		next;
	}

	if ($1 == "PipeHandle") {
		if ($5 == "0x00000002]") endpoint = "BULK_OUT";
		else if ($5 == "0x00000081]") endpoint = "BULK_IN";
		else if ($5 == "0x00000083]") {
			printf "%sURB %5d  skip\n", time, urb;
			ignore_urb = 1;
			way = "back";		# do as if we got the answer
			last_int_urb = urb;
			next;
		}
		else endpoint = "CONTROL";
	}

	if ($1 == "TransferBufferLength") buflen=strtonum("0x"$3);
	if ($1 == "RequestTypeReservedBits") rtype=strtonum("0x"$3);
	if ($1 == "Request") request=strtonum("0x"$3);
	if ($1 == "Value") value=strtonum("0x"$3);
	if ($1 == "Index") {
		rindex=strtonum("0x"$3);
		get_data = 0;
	}

	if ($4 == "(USBD_TRANSFER_DIRECTION_IN,") direction="IN";
	if ($4 == "(USBD_TRANSFER_DIRECTION_OUT,") direction="OUT";

        if( $2 ~ /URB_FUNCTION_/ ) {         # Added by JWD 21/10/2005
	        last_action = action;                                                    # Added by JWD 21/10/2005
		if ($2 == "URB_FUNCTION_VENDOR_DEVICE:") action="v";
		else if ($2 == "URB_FUNCTION_BULK_OR_INTERRUPT_TRANSFER:") action="b";
		else if ($2 == "URB_FUNCTION_CONTROL_TRANSFER:") action="c";
		else if ($2 == "URB_FUNCTION_GET_DESCRIPTOR_FROM_DEVICE:") action="d";  # Added by JWD 21/10/2005
		else if ($2 == "URB_FUNCTION_SELECT_CONFIGURATION:") action="s";        # Added by JWD 21/10/2005
		else action="?";# Added by JWD 21/10/2005
        }         # Added by JWD 21/10/2005

# Take care of the data
	if ($1 == "UrbLink") {
		get_data = 0;
		if (data_left != 0) {
# Saw this quite often with Plustek devices, it is not really a problem: gerhard@gjaeger.de
			printf("warning line %d (data left)\n", NR);
			data_left = 0;
#			exit;
		}
	}

	if (get_data) {
		if (data_left > 16)
			data_len = 16;
		else
			data_len = data_left;

		if (NF == (data_len+1)) {
			data_left = data_left - data_len;

			for (i=0; i<data_len; i++) {
				buffer[data_index] = strtonum("0x"$(i+2));
				data_index ++;
			}
		} else {
# Saw this quite often with Plustek devices, it is not really a problem: gerhard@gjaeger.de
			printf("warning: line %d, expected 0x%x bytes, missing 0x%x\n", NR, buflen, data_left);
			data_left = 0;
			get_data  = 0;
#			exit;
		}
	}

# We don't want to get data all the time.
	if ($1 == "TransferBufferMDL") {
		if ((direction == "OUT" && way == "down") ||
			(direction == "IN" && way == "back")) {
			
			get_data = 1;
			data_left = buflen;
			data_index = 0;
		}
	}
}